import processing.opengl.*;

int speed = 4; //pixels per Frame
int breite = 8;
int anzahl = 100;
Stripe[] stripes = new Stripe[anzahl];
color colorNow = color(int(random(20,255)),int(random(20,255)), int(random(0,255)));
color backgroundColor = color(0,0,0);

boolean growing = false;
int Person_minFramePause = 1; // darf nicht kleiner als 1 sein !!!
int Person_maxFramePause = 6;
int personDisplay;
PFont arial;

class Person {
  int speed, startSpeed, position, nextFrame;
  color c;
  Person (){
    this.restart(0);
  }
  void restart(int pause) {
    //position
    int f = int(random(-5,5));
    if (f < 0) {
      position = 0;
    } else {
      position = -stripes.length+1;
    } 
    
    //speed
    startSpeed = speed = int(random(Person_minFramePause,Person_maxFramePause));
    
    //nextFrame
    nextFrame = frameCount + speed + pause;
    
    //color
    c = color(int(random(20,255)),int(random(20,255)), int(random(0,255)));
  }
}

Vector persons = new Vector();


void setup() {
  size(800,300, OPENGL);
  background(0,0,0);
  fill(0, 153);
  noStroke();
  frameRate(30);
  for (int i = 0; i <anzahl; i++){
     stripes[i] = new Stripe(breite*i);
  }
  arial = createFont("Arial",14, true);
}
void draw(){
  if (!persons.isEmpty()) {
    for (int i = 0; i < persons.size(); i++) {
      Person pers = (Person)persons.get(i);
      if (frameCount == pers.nextFrame){
      
        if (abs(pers.position) < stripes.length) {
          stripes[abs(pers.position)].run(pers.c);
          pers.position++;
          int temp = round(random(pers.startSpeed / 2, pers.startSpeed*2));
          pers.speed = (temp < 1)? 1 : temp;
          pers.nextFrame = frameCount + pers.speed;
        } else {
          pers.restart(int(random(0,240)));
        }
      }
    }
  }
  if (frameCount < personDisplay){
    fill(110,110,110);
    textFont(arial);
    text(persons.size() + " person", 5, 14);
  } else if (frameCount < personDisplay + 20){
    fill(0,0,0,35);
    rect (5,0,65,18);
  }
  for (int i = 0; i < stripes.length; i++){
    stripes[i].update();
  }
}

void mouseMoved() {
  int i = floor(mouseX/breite);
  stripes[i].run(colorNow);
  if(mouseX <= 2  || mouseX >= width-3){
   colorNow = color(int(random(30,255)),int(random(30,255)), int(random(30,255)));
  }
}

void keyPressed(){
   if (key == CODED){
    if (keyCode == UP){
      if (speed < 30){
        speed += 1;
      }
    } else if (keyCode == DOWN){
      if (speed > 1) {
        speed -= 1;
      }
    } else if (keyCode == RIGHT){
      persons.add(new Person());
      personDisplay = frameCount + 30;
    } else if (keyCode == LEFT){
      if (!persons.isEmpty()){
        persons.remove(0);
        personDisplay = frameCount + 30;
      }
    }
    
  } else if (key == ' '){
    noLoop();
  }
}

void keyReleased(){
 if (key == ' '){
   loop();
 }
}

class Stripe extends Vector{
  int x;
  class Lamp {
     color c;
     int h;
     Lamp (color col, int hoehe){
       c = col;
       h = hoehe; 
     }
  }
  
  Stripe (int xpos){
   x = xpos;
  }
  
  void run(color c) {
    if (!this.isEmpty()){
      Lamp lamp = (Lamp)this.get(this.size()-1);
      if (lamp.c != c){
         this.add(new Lamp(c,0)); 
      }else {
       if (lamp.h > 30) {
         lamp.h -= 30;
       }
      }
    } else {
      this.add(new Lamp(c,0)); 
    }
  }
  void update(){
    for (int i = 0; i<this.size(); i++){
      Lamp lamp = (Lamp)this.get(i);
      lamp.h += speed;
      if (lamp.c != backgroundColor) {
        if (lamp.h < height) {
           fill(lamp.c, 5 );
          rect(x, 0, breite, lamp.h);
        }else{
          lamp.h = - speed * 50;
          lamp.c = backgroundColor;
        }
      }else {
       if (lamp.h > 0) { 
         if (lamp.h < height) {
           fill(lamp.c, 5);
           rect(x, 0, breite, lamp.h*0.5);
         }else if(lamp.h < height+255/5*speed*1.5){
           fill(lamp.c, 5);
           rect(x, 0, breite, height);
         }else {
           this.remove(i); 
         }
       }
      }
    }    
  }
}